summaryrefslogtreecommitdiffstats
path: root/protomsg.asm
blob: 286a336e26d176dff9fb892a75bd0c375aa2ccca (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
/* -*- asm -*- ----------------------------------------------------------- *
 *   
 *   Copyright 2013 H. Peter Anvin - All Rights Reserved
 *
 *   Permission is hereby granted, free of charge, to any person
 *   obtaining a copy of this software and associated documentation
 *   files (the "Software"), to deal in the Software without
 *   restriction, including without limitation the rights to use,
 *   copy, modify, merge, publish, distribute, sublicense, and/or
 *   sell copies of the Software, and to permit persons to whom
 *   the Software is furnished to do so, subject to the following
 *   conditions:
 *   
 *   The above copyright notice and this permission notice shall
 *   be included in all copies or substantial portions of the Software.
 *   
 *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
 *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
 *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
 *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
 *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
 *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
 *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 *   OTHER DEALINGS IN THE SOFTWARE.
 *
 * ----------------------------------------------------------------------- */

#include "v9fs.h"

	.code16
	.section ".rtext","ax"

/* ------------------------------------------------------------------------- *
 *  path_walk
 *
 *  Issue a walk message for the path (absolute path starting in \) in FS:SI.
 *  BX marks the end of the path to convert, and EAX is the new fid.
 *  On successful exit, CF=0 and %al contains the QID type.
 *  On error, CF=1 and %ax contains the Linux error number.
 * ------------------------------------------------------------------------- */

GPROC(path_walk_asciiz)
	call get_end_path	/* Point BX to the end of string */
	/* jmp path_walk */
END(path_walk_asciiz)
	
GPROC(path_walk)
	movw msgbuf7,%di
	movl $FID_ROOT,(%di)
	movl %eax,4(%di)
	addw $8,%di
	pushw %di
	incw %si		/* Skip leading backslash */
	call genpath
	popw %si
	pushw (%si)		/* Number of pathname chunks */
	movb $P9_TWALK,%al
	call simple_message
	jc 1f			/* Message error */
	popw %dx
	movw (%di),%cx		/* %cx = nwqid */
	imul $13,%cx,%bx	/* Each qid is 13 bytes */
	jz 4f			/* Special case for the root directory */
	movb -11(%bx,%di),%al	/* Type of the final QID */
	cmpw %dx,%cx
	jne 2f
	clc			/* All good */
1:
	retw
2:
	/*
	 * We receieved a subset of the desired qids.  If the final
	 * component is a directory, this is ENOENT, otherwise ENOTDIR.
	 */
	andb %al,%al
	movw $L_ENOENT,%ax
	jns 3f			/* Bit 7 = P9_QTDIR */
	movw $L_ENOTDIR,%ax
3:
	stc
	retw
4:
	/* It is the root directory, so we get zero qids back */
	movb $P9_QTDIR,%al
	/* CF = 0 already */
	retw
END(path_walk)

/* ------------------------------------------------------------------------- *
 *  clunk
 *
 *  Clunks the FID in %eax
 * ------------------------------------------------------------------------- */

GPROC(clunk)
	movw msgbuf7,%di
	stosl
	movb $P9_TCLUNK,%al
	jmp simple_message
END(clunk)